1、什么是Unicode？
Unicode是一个编码方案，是为了解决传统的字符编码方案的局限而产生的。Unicode 为每种语言中的每个字符设定了统一并且唯一的二进制编码，以满足跨语言、跨平台进行文本转换、处理的要求。简单讲，对于我们遇到的每一个特殊字符，它都有唯一对应的Unicode。
2、Unicode与特殊字符的对应举例
Unicode编码则是采用双字节16位来进行编号，可编65536字符，基本上包含了世界上所有的语言字符，它也就成为了全世界一种通用的编码，而且用十六进制4位表示一个编码，非常简结直观。具体的特殊字符与Unicode的编码对应关系可以从这个网页中查询，Unicode编码表。
2.1 Unicode编码表
简单介绍一下这个编码表如何使用，表格内的每一个字符的Unicode编码为其对应的第一列的十六进制数字+第一行的十六进制数字。举些例子，! 的Unicode编码为0020 + 1= 0021；#的Unicode编码为0020 + 3 = 0023； / 的Unicode编码为0020 + F = 002F。
2.2 利用WORD查询Unicode编码
除了利用现成的编码表外，我们也可以通过，Office办公软件Word来查询特殊字符的Unicode编码。
Word软件中，可以插入特殊字符，在面板中选中特殊字符后，会显示特殊字符的Unicode的名称和对应编码。我们可以看一下!, #, / 对应的名称和编码：
Unicode name: Exclamation Mark; Character code: 0021.
Unicode name: Number Sign; Character code: 0023.
Unicode name: Solidus; Character code: 002F.
3、SAS输出Unicode特殊字符的几种情况
SAS中使用{UNICODE}文本命令，将特殊字符放入文本中，主要有以下3种应用情况：
- 使用字符的十六进制Unicode编码，例如，
{unicode "03b1"x}，也可以使用{unicode 03b1}； - 使用字符的常用关键字，例如，
{unicode beta}; - 解析为字符对应的十六进制值或关键字的动态值，例如，
{unicode _var}， _var值为字符的十六进制值或关键字。
{UNICODE}命令在使用过程种还需要区分是否在引号内：
-
如果命令在引号内( inside quotes )，需要对其进行转义(Specifications are escaped)，例如，
"(*ESC*){unicode beta}"。如果不使用(*ESC*)进行转义，“命令”就是单纯的字符含义了。 (临床试验SAS编程中所遇到的特殊字符，绝大多数情况都在引号中，需要进行转义！) - 如果命令不在引号内(outside quotes)，就不需要转义了，直接使用，例如，
{unicode beta}。
常用特殊字符Unicode命令举例：
来源：Unicode and Special Characters
4、特殊字符在SAS ODS输出中的具体应用举例
我介绍三个常用的例子：
- Title、Footnote中的特殊字符，直接在Title、Footnote语句种使用{unicode}命令，若内容在引号中，需对{unicode}进行转义。
ods rtf file="../class.rtf";
title "Special char: Plus or minus, (*ESC*){unicode 00b1}";
footnote "Special char: y hat sub i, y(*ESC*){unicode hat}(*ESC*){sub i}";
proc print data=sashelp.class;
run;
ods rtf close;
- 数据集中特殊字符输出到RTF文件中，将{unicode}命令赋值给变量，直接输出到对应的目标文件中。这里有一个注意点，变量长度一定要大于等于{unicod}命令的字符长度，否则命令会发生截断，显示为普通字符串。
在SASHELP.CLASS中新建一个变量Sex_：
Set to alpha, if Sex=‘M’;
Set to beta, if Sex='F'.
ods rtf file="../class.rtf";
title "Male: (*ESC*){unicode alpha}; Female: (*ESC*){unicode beta}";
data class;
set sashelp.class;
if sex="M" then sex_="(*ESC*){unicode alpha}";
else if sex="F" then sex_="(*ESC*){unicode beta}";
run;
proc print data=class;
run;
ods rtf close;
-
Figure中的特殊字符表达，自定义Legend的Label，实现特殊字符的输出。
Figure中的特殊字符主要出现在Legend部分，我们来举一个例子。出图的代码参照这篇文章，SAS如何生成散点图(Scatter Plot)--临床试验中具体应用。
***Create template;
proc template;
define statgraph scatterplot;
begingraph;
layout overlay/
yaxisopts=(
label = "Height" labelattrs = (size = 7) tickvalueattrs=(size=7pt)
linearopts=(ViewMin=50 ViewMax=80 tickValueSequence=(start = 50 end = 80 increment = 5))
)
xaxisopts=(
label = "Weight" labelattrs = (size = 7) tickvalueattrs=(size=7pt)
linearopts=(ViewMin=40 ViewMax=150 tickValueSequence=(start = 40 end = 150 increment = 10))
);
scatterplot y = height x = weight / group = sex name = "scatter";
regressionplot y = height x = weight / group = sex name = "fitline";
discretelegen "scatter" / border=false;
endlayout;
endgraph;
end;
run;
***Render Template;
proc sort data=sashelp.class out=class;
by sex;
run;
proc sgrender data=class template=scatterplot;
run;
以上代码，运行的输出结果如下，Legend显示的分组变量Sex的原始值。
通常如果我们希望Legend显示特定的格式，我们通常会直接加上Format语句，使Legend显示对应的格式。
proc format;
value $sex
"M"="Male"
"F"="Female"
;
run;
proc sgrender data=class template=scatterplot;
format sex $sex.;
run;
如果这时候将格式换成使特殊字符会是什么情况呢？过程步SGRENDER在引用这个Format时发生了某种错误，具体什么错误，我也不清楚。
proc format;
value $sex_
"M"="(*ESC*){unicode alpha}"
"F"="(*ESC*){unicode beta}"
;
run;
proc sgrender data=class template=scatterplot;
format sex $sex_.;
run;
为避免上面错误的发生，我们可以选择自定义Legen属性，参考SAS如何生成散点图(Scatter Plot)--临床试验中具体应用，将Legend的Label设置为特殊字符，再进行调用，可以成功显示特殊字符。
legenditem type=marker name="F" /label = "(*ESC*){unicode alpha}" markerattrs = (color=red symbol=triangle);
legenditem type=marker name="M" /label = "(*ESC*){unicode beta}" markerattrs = (color=green symbol=circle);
layout overlay/
···
···
discretelegend "F" "M" / displayclipped=true across=2 border=false;
···
···
endlayout;
以上就是SAS中ODS图形输出Unicode字符的分享，若有疑问，欢迎评论区交流！
