一.立方体纹理（CubeMap）
CubeMap 是六个假想面的集合，这六个面对应着一个正方体的 6 个面，每个面表示沿着世界空间下的轴向观察所得的图像。CubeMap是环境映射的一种实现方式。
立方体纹理采样，对立方体纹理采样需要提供一个三维的纹理坐标，表示的是世界空间下的3D方向。在采样时，从立方体中心出发，向采样的方向发射，与某个面相交的的部分就是采样的结果。
对立方体纹理的采样
使用立方纹理好处在于，实现简单而且效果还可以。但它的缺点是当新引入了光源，物体，或是有物体发生移动时也重新生成立方体纹理。而且立方体纹理也仅可以反射环境，而不能反射使用了同一立方体纹理的物体本身（自反射）。因为立方体纹理不能模拟多次反射的结果，如两金属球相互反射。所以如果使用立方体纹理尽量使用凸多边形，而不使用凹多边形，因为凹多边形会反射物体本身。
CubeMap在实时渲染中最常见的应用是天空盒子（Skybox）和环境影射。
1.1. 天空盒子（Skybox）
在Unity中设置天空盒很容易，只要创建一个Skybox材质，然后赋予相关摄像机就可以。且将摄像机的Clear Flags设为SkyBox，同时需要将六张纹理的Wrap Mode 设置为Clamp。
1.2. 环境映射
立方体纹理最常见的用处是用于环境映射，用这种方法可以模拟出带有金属质感的材质。创建用于环境映射的立方体纹理的方法有三种：
第一种是直接由一些特殊布局的纹理创建，只需把纹理的TextureType设置为Cubemap即可。
第二种是手动创建Cubemap，再把6张图赋给Cubemap
第三种是脚本生成
官方推荐使用第一种方法，因为这样可以对纹理数据进行压缩，而且支持边缘修正，光滑反射（glossy reflection），HDR等功能。第二种就是类似天空盒设置立方体纹理的过程（见上一篇）。第三种则可以根据不同的场景不同的物体生成不同的立方体纹理（Camera.RenderToCubemap）。
环境映射最常见的应用是反射和折射。
二.反射
使用了反射效果的物体通常看起来像镀了层金属。
原理：通过入射光线的方向和表面法线方向来计算反射方向，再利用反射方向来对立方体纹理采样即可。
实现要点：
_ReflectAmount 控制整体反射程度，_Cubemap 表示要输入的立方体纹理，用来存储反射结果
reflect函数实现顶点的反射方向
texCUBE 函数对立方体纹理采样
完整代码：
Shader "Unity Shaders Book/Chapter 10/Reflection" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_ReflectColor ("Reflection Color", Color) = (1, 1, 1, 1)
_ReflectAmount ("Reflect Amount", Range(0, 1)) = 1
_Cubemap ("Reflection Cubemap", Cube) = "_Skybox" {}
}
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry"}
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed4 _ReflectColor;
fixed _ReflectAmount;
samplerCUBE _Cubemap;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldPos : TEXCOORD0;
fixed3 worldNormal : TEXCOORD1;
fixed3 worldViewDir : TEXCOORD2;
fixed3 worldRefl : TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
// Compute the reflect dir in world space
o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 worldViewDir = normalize(i.worldViewDir);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));
// Use the reflect dir in world space to access the cubemap
fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
// Mix the diffuse color with the reflected color
fixed3 color = ambient + lerp(diffuse, reflection, _ReflectAmount) * atten;
return fixed4(color, 1.0);
}
ENDCG
}
}
FallBack "Reflective/VertexLit"
}
实现效果如下：
三.折射
光从一种介质进入另一种具有不同折射率的介质，或者在同一种介质中折射率不同的部分运行时，由于波速的差异，使光的运行方向改变的现象就称为光的折射。
而光在发生折射时入射角与折射角符合斯涅耳定律：
n1和n2分别表示两个介质的折射率。
实现要点：
_RefractRatio，代表不同介质的透射比；
refract函数计算折射方向，第一个参数为入射光线的方向（归一化），第二个是表面法线(归一化)，第三个参数是入射光线所在介质的折射率和折射光线所在介质的折射率的比值；
完整代码：
Shader "Unity Shaders Book/Chapter 10/Refraction" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_RefractColor ("Refraction Color", Color) = (1, 1, 1, 1)
_RefractAmount ("Refraction Amount", Range(0, 1)) = 1
_RefractRatio ("Refraction Ratio", Range(0.1, 1)) = 0.5
_Cubemap ("Refraction Cubemap", Cube) = "_Skybox" {}
}
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry"}
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed4 _RefractColor;
float _RefractAmount;
fixed _RefractRatio;
samplerCUBE _Cubemap;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldPos : TEXCOORD0;
fixed3 worldNormal : TEXCOORD1;
fixed3 worldViewDir : TEXCOORD2;
fixed3 worldRefr : TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
// Compute the refract dir in world space
o.worldRefr = refract(-normalize(o.worldViewDir), normalize(o.worldNormal), _RefractRatio);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 worldViewDir = normalize(i.worldViewDir);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));
// Use the refract dir in world space to access the cubemap
fixed3 refraction = texCUBE(_Cubemap, i.worldRefr).rgb * _RefractColor.rgb;
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
// Mix the diffuse color with the refract color
fixed3 color = ambient + lerp(diffuse, refraction, _RefractAmount) * atten;
return fixed4(color, 1.0);
}
ENDCG
}
}
FallBack "Reflective/VertexLit"
}
效果如下图：
四. 菲涅耳反射
菲涅耳反射描述了一种光学现象，当光线照射到物体表面上时，一部分发生反射，一部分进入内部，发生折射或者散射。被反射的光和入射光线之间存在一定的比例关系，这个比例关系可以通过菲涅耳等式进行计算。
举个发生菲涅耳反射的现象例子：
而菲涅耳等式有两条应用广泛的近似等式：
1.Schlick 菲涅耳近似等式 ：
v 是视角方向，n 是表面法线，F0 是反射系数
2.Empricial 菲涅耳近似等式：
实现完整代码：
Shader "Unity Shaders Book/Chapter 10/Fresnel" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_FresnelScale ("Fresnel Scale", Range(0, 1)) = 0.5
_Cubemap ("Reflection Cubemap", Cube) = "_Skybox" {}
}
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry"}
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed _FresnelScale;
samplerCUBE _Cubemap;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldPos : TEXCOORD0;
fixed3 worldNormal : TEXCOORD1;
fixed3 worldViewDir : TEXCOORD2;
fixed3 worldRefl : TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 worldViewDir = normalize(i.worldViewDir);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb;
fixed fresnel = _FresnelScale + (1 - _FresnelScale) * pow(1 - dot(worldViewDir, worldNormal), 5);
fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));
fixed3 color = ambient + lerp(diffuse, reflection, saturate(fresnel)) * atten;
return fixed4(color, 1.0);
}
ENDCG
}
}
FallBack "Reflective/VertexLit"
}
实现效果如下：
_FresnelScale 为 0 时，物体具有边缘光照效果的漫反射
