立方体纹理应用
环境映射
立方体纹理最常见的用处是用于环境映射，用这种方法可以模拟出带有金属质感的材质。创建用于环境映射的立方体纹理的方法有三种：第一种是直接由一些特殊布局的纹理创建，第二种是手动创建Cubemap，再把6张图赋给Cubemap，第三种是脚本生成。
官方推荐使用第一种方法，因为这样可以对纹理数据进行压缩，而且支持边缘修正，光滑反射（glossy reflection），HDR等功能。第二种就是类似天空盒设置立方体纹理的过程（见上一篇）。第三种则可以根据不同的场景不同的物体生成不同的立方体纹理（Camera.RenderToCubemap）。
第一种
第一种
反射
有了立方体纹理之后就可以使用环境映射技术。最常见的就是反射和折射。
使用了反射效果的物体通常看起来就像镀了一层金属。模拟反射效果只需要根据光线的入射方向和表面的法线，算出出射方向，然后根据这个方向对立方体纹理进行采样。
Shader "Unlit/Reflection"
{
Properties{
_Color("Color Tint",Color)=(1,1,1,1)
_ReflectColor("Reflection Color",Color)=(1,1,1,1)
_ReflectAmount("Reflection Amount",Range(0,1))=1
_Cubemap("Reflection Cubemap",Cube)="_Skybox"{}
}
SubShader{
Tags{"RenderType"="Opaque" "Queue"="Geometry"}
Pass{
Tags{"LightModel"="FowardBase"}
CGPROGRAM
#pragma multi_compile_fwbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed4 _ReflectColor;
float _ReflectAmount;
samplerCUBE _Cubemap;
struct a2v
{
float4 vertex:POSITION;
float3 normal:NORMAL;
};
struct v2f
{
float4 pos:SV_POSITION;
float3 worldPos:TEXCOORD0;
fixed3 worldNormal:TEXCOORD1;
fixed3 worldViewDir:TEXCOORD2;
fixed3 worldReflect:TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldViewDir = UnityWorldSpaceViewDir(-o.worldPos);
//这个地方将视线当做入射光线，否则就是得需要算出各个方向上的光线，其实结果都是一样
o.worldReflect = reflect(-o.worldViewDir,o.worldNormal);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldViewDir = normalize(i.worldViewDir);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffise = _LightColor0.rgb * _Color.rgb * saturate(dot(worldNormal,worldLightDir));
//用反射方向直接采样立方体纹理
fixed3 reflection = texCUBE(_Cubemap,i.worldReflect).rgb*_ReflectColor.rgb;
UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);
fixed3 color = ambient + lerp(diffise,reflection,_ReflectAmount)*atten;
return fixed4(color,1.0);
}
ENDCG
}
}
}
反射
折射
折射的原理：当光从一种介质斜射入另一种介质时，传播方向一般会发生改变。当给定入射角时，我们可以使用斯涅耳定律来计算反射角，公式：
η1sinθ1=η2sinθ2
其中η是两种介质的折射率，折射率是一项重要的物理常数，例如真空的折射率为1，玻璃的折射率一般是1.5。
折射
在实时渲染中在得到折射方向后会直接去cubemap中采样，但是这并不符合物理规律，因为实际中光折射进介质后还可以在介质内部射出来。
Shader "Unlit/Refraction"
{
Properties{
_Color("Color Tint",Color)=(1,1,1,1)
_RefractColor("Refract Color",Color)=(1,1,1,1)
_RefractAmount("Refracttion Amount",Range(0,1))=1
_RefractRatio("Refraction Ratio",Range(0.1,1))=0.5
_Cubemap("Refraction Cubemap",Cube)="_Skybox"{}
}
SubShader{
Tags{"RenderType"="Opaque" "Queue"="Geometry"}
Pass{
Tags{"LightModel"="ForwardBase"}
CGPROGRAM
#pragma multi_compile_fwbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed4 _RefractColor;
float _RefractAmount;
fixed _RefractRatio;
samplerCUBE _Cubemap;
struct a2v
{
float4 vertex:POSITION;
float3 normal:NORMAL;
};
struct v2f
{
float4 pos:SV_POSITION;
float3 worldPos:TEXCOORD0;
float3 worldNormal:TEXCOORD1;
float3 worldViewDir:TEXCOORD2;
fixed3 worldRefra:TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
//这个地方也是将视线方向当做光线入射方向
o.worldRefra = refract( -normalize(o.worldViewDir),normalize(o.worldNormal),_RefractRatio);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldViewDir = normalize(i.worldViewDir);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * _Color.rgb * saturate(dot(worldLightDir,worldNormal));
fixed3 refract = texCUBE(_Cubemap,i.worldRefra).rgb * _RefractColor.rgb;
UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);
fixed3 color = ambient + lerp(diffuse,refract,_RefractAmount)*atten;
return fixed4(color,1.0);
}
ENDCG
}
}
}
折射
菲涅耳反射
在实时渲染中经常会使用菲涅耳反射（Fresnel Reflection）来根据视角方向控制反射程度。菲涅耳反射描述了一种光学现象，即当光线照射到物体表面时，一部分发生反射，一部分进入物体内部，发生折射或散射。被反射的光和入射光之间存在一定的比率关系，这个比率关系可以通过菲涅耳等式进行计算，几乎任何物体都或多或少的存在菲涅耳效果，Everything has Fresnel，这篇文章说明了现实中很多具有菲涅耳效果的例子。
现实世界中的菲涅耳等式很复杂，所以在实时渲染中通常使用一些近似公式来计算。
Schlick菲涅耳近似等式：
Schlick菲涅耳近似等式
其中F0是反射系数，用于控制菲涅耳反射强度，v是视角方向，n是表面法线。
Empricial菲涅耳近似等式：
Empricial菲涅耳近似等式
其中bias、scale、power为控制项。
使用菲涅耳近似等式可以用来模拟在边界处折射光强和反射光强与漫反射光强之间的变化。在许多车漆、水面等材质渲染中，经常使用菲尼耳反射来模拟更加真实的反射效果。
Shader "Unlit/Schlik_Fresnel"
{
Properties{
_Color("Color",Color)=(1,1,1,1)
_FresnelScale("Fresnle Scale",Range(0,1))=1
_Cubemap("CubeMap",Cube)= "_Skybox" {}
}
SubShader{
Tags{"RenderType"="Opaque" "Queue"="Geometry"}
Pass{
Tags{"LightModel"="ForwardBase"}
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
fixed _FresnelScale;
samplerCUBE _Cubemap;
struct a2v
{
float4 vertex:POSITION;
float3 normal:NORMAL;
};
struct v2f
{
float4 pos:SV_POSITION;
float3 worldPos:TEXCOORD0;
float3 worldNormal:TEXCOORD1;
float3 worldViewDir:TEXCOORD2;
float3 worldReflect:TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
o.worldReflect = reflect(-o.worldViewDir,o.worldNormal);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i):SV_TARGET
{
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldViewDir = normalize(i.worldViewDir);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * _Color.rgb * saturate(dot(worldLightDir,worldNormal));
fixed3 reflect = texCUBE(_Cubemap,i.worldReflect).rgb;
fixed fresnel = _FresnelScale + (1-_FresnelScale)*pow(1-dot(worldViewDir,worldNormal),5);
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
//用菲涅耳近似等式算出的值来控制折射或是反射与漫反射之间的变化
fixed3 color = ambient + lerp(diffuse,reflect,saturate(fresnel))*atten;
return fixed4(color,1.0);
}
ENDCG
}
}
}
菲涅耳反射系数：1
发现全是反射效果
菲涅耳反射系数：0
全是漫反射效果，但是边界处有反射效果。
