二维噪声（纹理程序）

书名：代码本色：用编程模拟自然系统
作者：Daniel Shiffman
译者：周晗彬
ISBN：978-7-115-36947-5

0.6.2　二维噪声

1、工作方式的对比

在一维噪声中，噪声序列中的邻近噪声值都非常接近，因为在一维空间中，每个点只有两个相邻点：前一个点（在图中位于左侧）和后一个点（位于右侧）。

图0-10　一维噪声

图0-11　二维噪声

从概念上看，二维噪声的工作方式是完全一样的。唯一的不同在于：二维噪声从线性空间转到了网格空间。

2、纹理效果

思考下面的场景：一张纸上有个表格，在表格的每个单元格里写一个数字，每个单元格的数字都接近和它相邻单元格上的数字，即上下左右和对角线上的值。
试着把表格上的数据可视化：把单元格上的数字映射成色彩亮度，你就能看到云状的图形。
在图形中，白色和浅灰色相邻、浅灰色和灰色相邻、灰色和深灰色相邻、深灰色又和黑色相邻，以此类推，参见下图。

这就是噪声最先被引入时的用途。只要稍微改变一下参数，你就可以创造出有大理石、树木和其他自然纹理效果的图像。

3、在Processing中使用二维噪声

1、如果要给窗口中的每个像素着上随机的颜色，你要写一个循环，在循环中遍历每个像素点并选择一个随机的亮度。

loadPixels();
for (int x = 0; x < width; x++) {
    for (int y = 0; y < height; y++) {
        float bright = random(255); 随机亮度
        pixels[x+y*width] = color(bright);
    }
  } 
updatePixels();

2、下面要根据noise()函数的返回值为像素着色，我们只需要调用noise()函数，取代原先的random()函数。

float bright = map(noise(x,y),0,1,0,255); 由Perlin噪声算法产生的亮度！

$\color {red}{最大的差别就是Perlin噪声产生的点的亮度是平滑的！}$
从表面上看，这并没有问题，你会在二维空间上的每个(x,y)位置得到对应的噪声值。
但问题是我们并不能由此得到云质感的效果。(怎样改进？)
对噪声函数来说，从200到201像素会造成很大的参数跳跃。
还记得吗，在一维噪声中，我们每次以0.01的增幅递增时间变量，并不是1这么大的增量。（原因）
对此，我们可以用不同的变量作为噪声函数的参数，这样就可以解决这个问题。
比如，我们可以增加xoff和yoff变量：在循环遍历过程中，如果有水平方向的移动，就以合适的增量递增xoff，如果有竖直方向的移动，就递增yoff。

4、实例

float increment = 0.01;

void setup() {
  size(400,300);
  noLoop();
}

void draw() {
  background(0);
  
  // Optional: adjust noise detail here
  // noiseDetail(8,0.65f);
  
  loadPixels();

  float xoff = 0.0; // Start xoff at 0
  
  // For every x,y coordinate in a 2D space, calculate a noise value and produce a brightness value
  for (int x = 0; x < width; x++) {
    xoff += increment;   // Increment xoff 
    float yoff = 0.0;   // For every xoff, start yoff at 0
    for (int y = 0; y < height; y++) {
      yoff += increment; // Increment yoff
      
      // Calculate noise and scale by 255
      float bright = noise(xoff,yoff)*255;

      // Try using this line instead
      //float bright = random(0,255);
      
      // Set each pixel onscreen to a grayscale value
      pixels[x+y*width] = color(bright);
    }
  }
  
  updatePixels();
}

increment 取 0.01，图形比较细腻，取值大，则粗糙。

5、Perlin噪声的几种常规用法

对一维噪声，我们把平滑的噪声值当作物体的位置，并由此描绘游走的轨迹。
对二维噪声，我们用平滑的噪声值制作了一副有云纹理的图形

Perlin噪声值仅仅是一组数据，并不一定是像素位置或者色彩亮度

当我们在对风力进行建模时，风力的大小就是由Perlin噪声生成的
分形模型中树枝之间的角度
模拟流场时物体的速度和方向，都可能是由Perlin噪声生成的。