一招解决打包自动上次蒲公英平台

每次发测试包，需要调用android打包命令，然后在打开浏览器上次到蒲公英平台，给测试下载。虽然每次只需要几分钟，但是每次几分钟太浪费时间了。做为程序员的我，懒才能完美形容。既然是重复操作，那为什么不写个脚本打包完成后自动上传到对应的平台呢？
说干就干，翻阅蒲公英平台的接口文档，发现正好有上传apk的api

首先就是用什么方式上传，由于目前android大多使用okhttp作为网络请求，所以在gradle当然使用okhttp作为网络请求库洛，蒲公英接口返回的格式是json当然会用到google官方的gson作为json解析，然后就有了如下配置，在项目根目录的build.gradle中添加下面依赖

buildscript {
    
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.4.2'
        classpath "com.squareup.okhttp3:okhttp:3.14.2"
        classpath "com.google.code.gson:gson:2.8.5"

    }
}

然后在app所在的build.gradle文件中开始写我们的自动上传脚本洛，开心愉快的使用开始了

android{
    // 注意这个task后面的名字哦，后面会用的到，随便写啥都可以的
     task assembleUat2UploadPgyer() {
        dependsOn "assembleRelease" //  这里写打包的脚本名称，可以是发布版本，debug版本，或者是自定义的版本
        group "upload2Pgyer" // 给我们这个脚本取个名字，方便找到哦，不然都跑到other里面了，太难找了
        doFirst {
            logger.log(LogLevel.ERROR, "开始执行apk上传蒲公英操作")
        }
        doLast {
            applicationVariants.all {
                it.outputs.each { out ->
                    def outputFile = out.outputFile
                    if (outputFile != null && outputFile.name == 'app-release.apk') { // 这里的app-release要根据上面配置的assembleXXX来写哦
                        logger.log(LogLevel.ERROR, "apk 所在的磁盘绝对路径 : ${outputFile.absolutePath}")
                        // 还是那个字懒，发版本不想去修改版本号，所以就用git提交的次数作为版本号了
                        def versionCode = 'git rev-list HEAD --first-parent --count'.execute().text.trim().toInteger()
                        logger.log(LogLevel.ERROR, "app 当前准备传版本号：${rootProject.ext.android.versionName}.${versionCode}")

                        def clientBuilder = new OkHttpClient.Builder()
                        clientBuilder.connectTimeout(10, TimeUnit.SECONDS)
                        clientBuilder.readTimeout(60, TimeUnit.SECONDS)
                        OkHttpClient client = clientBuilder.build()


                        def fileBody = RequestBody.create(MediaType.parse("multipart/form-data"), new File(outputFile.absolutePath))
                        def bodyBuilder = new MultipartBody.Builder()
                                .setType(MultipartBody.FORM)
                                .addFormDataPart("_api_key", "蒲公英的key")
                                .addFormDataPart("file", outputFile.name, fileBody)
                                .addFormDataPart("buildInstallType", "1")
                                // .....后面还可以添加很多参数，可以去看蒲公英的文档
                        def request = new Request.Builder()
                                .url("https://www.pgyer.com/apiv2/app/upload")
                                .post(bodyBuilder.build())
                                .build()

                        logger.log(LogLevel.ERROR, "-----------开始上传-------------")


                        def response = client.newCall(request).execute()

                        if (response == null || response.body() == null) {
                            logger.log(LogLevel.ERROR, "蒲公英上传结果失败")
                            return null
                        }
                        def json = response.body().string()
                        logger.log(LogLevel.ERROR, "蒲公英上传结果:${json}")
                        def data = new Gson().fromJson(json, Map.class).data
                        logger.log(LogLevel.ERROR, "蒲公英安装二维码地址:${data.buildQRCodeURL}")
                        logger.log(LogLevel.ERROR, "蒲公英上传成功的版本号:${data.buildVersion}.${data.buildVersionNo}")
                        logger.log(LogLevel.ERROR, "蒲公英下载地址:https://www.pgyer.com/${data.buildShortcutUrl}")

                        response.close()
                        logger.log(LogLevel.ERROR, "-----------完成上传-------------")
                    }
                }
            }
        }
    }
}

到此我们的自动上次脚本就完成啦，不对，还有一个重要的使用，忘记导包了，O(∩_∩)O哈哈~

import okhttp3.MultipartBody
import okhttp3.OkHttpClient
import okhttp3.Request
import okhttp3.RequestBody
import okhttp3.MediaType
import java.util.concurrent.TimeUnit
import com.google.gson.Gson

这样才算完成哦

看看最后的效果洛
在android studio Gradle工具栏中就可以看见我们自定义的一个task，每次需要发布测试版本，就疯狂的点击这个就好啦，一切交给我们脚本吧
脚本执行完后就会在控制台输出对应的下载地址哦，复制粘贴发给测试，轻松加愉快的完成了版本发布

哈哈，其实可以把这段脚本抽取出来的，懒才是我的天性，所以就没有抽取，能够完成功能的脚本才是好脚本，所以就没有这么多讲究了哦
emmmmm，其实这个脚本还有一个问题，就是在上传的时候没有进度显示。由于使用了okhttp想要获取上传的进度，需要自定义写东西，我太懒了，不想搞了，还是那个原则，能用的脚本就是好脚本。有兴趣的小伙伴可以加入进度条哦