stata结果导入excel-多重响应

前段时间知道stata16可以直接导入SPSS数据，就把stata16安装了

然后，就想了解stata16的新功能，官方介绍：New in Stata 16

最开始，是里面的Reproducible reporting吸引我，毕竟一直在想着怎么写动态分析报告，即分析结果和报告同步更新。

就研究了一下里面提到的dyndoc，putexcel，putword命令

首先，就是研究了putexcel命令，想着把频率分析结果能直接导入excel，尤其是有大量变量的时候

简单尝试了一下，发现还是很好用，尤其是导出来中文不会乱码，而且格式自定义，其他命令如logout，asdoc等都有各种问题的。

接下来，分不同帖子写写不同分析结果如何批量导出结果至excel，

首先是，stata结果导入excel-频率分析

接着是，多重响应分析结果导出excel

1. 思路

总的来说，思路都是先分析出结果组成矩阵，再导出excel：

在stata中将多重响应结果形成矩阵（即多重响应结果表）；
再将矩阵导入excel；
根据每个矩阵行数，自动在上个矩阵结束后空一行，导入新的矩阵；
通过循环，只需添加变量名，则自动生成新的表；

2. 所有代码

第一部分：设置
local rownum=1
local rntable=1
putexcel set result.xlsx,sheet("多选题",replace) modify

第二部分：循环
foreach i of varlist P3Q2 P3Q11 P3Q27{

第三部分：多重响应分析结果构成矩阵
mrtab `i'S*
mat freq=r(responses)
mata:st_matrix("sum", colsum(st_matrix("freq")))
matrix rowjoin freq=freq sum
mat per=(freq/sum[1,1],freq/r(N))
mat coljoin multable=freq per
matrix rownames multable=`r(list) ' "总计"
matrix colnames multable="频率" "响应百分比" "个案百分比"

第四部分：结果导出excel
putexcel a`rownum'=matrix(multable),names txtwrap
local rntable:rowsof multable
local rownum=`rownum'+`rntable'+2
putexcel c1:d`rownum',nformat(#.00%) 
}

3.代码解释

第一部分：设置

local rownum=1
local rntable=1
putexcel set result.xlsx,sheet("多选题",replace) modify

与 stata结果导入excel-频率分析相同

第二部分：循环

foreach i of varlist P3Q2 P3Q11 P3Q27{

多选题拆分后的变量一般是P3Q2S1,P3Q2S2,P3Q2S3……，因此，只需要对变量名前S进行循环

第三部分：多重响应分析结果构成矩阵

mrtab `i'S*

以变量P3Q2为例，通过输入ssc install mrtab安装命令mrtab，将拆分后的变量放在命令mrtab后，P3Q2S*表示P3Q2S1,P3Q2S2,P3Q2S3……

结果如下：

mrtab.png

上述命令存储的结果如下：

存储结果.png

r(N)为有效样本量，r(N_missing)为缺失样本量，r(r)为选项数量；

r(list)为选项内容，r(type)为变量类型（字符或数值）；

矩阵r(responses)为每个选项的频率；

mat freq=r(responses)

将矩阵r(responses)命名为freq

mata:st_matrix("sum", colsum(st_matrix("freq")))

在mata语言中，计算矩阵freq中这一列所有元素的和，并存到矩阵sum中，再传回stata

即得到矩阵sum：

矩阵sum.png

matrix rowjoin freq=freq sum

将矩阵freq和sum进行拼接，更新矩阵freq：

mat per=(freq/sum[1,1],freq/r(N))

生成百分比矩阵per，包括响应百分比和个案百分比：

矩阵per.png

mat coljoin multable=freq per

矩阵freq和per拼接成矩阵multable:

矩阵multable.png

matrix rownames multable=`r(list) ' "总计"
matrix colnames multable="频率" "响应百分比" "个案百分比"

修改矩阵multable的行名和列名：

矩阵multable带名.png

第四部分：结果导出excel

putexcel a`rownum'=matrix(multable),names txtwrap

将矩阵multable导入Excel中，带矩阵行列名，自动换行

local rntable:rowsof multable
local rownum=`rownum'+`rntable'+2

更新暂元rntable和rownum，便于下次循环

putexcel c1:d`rownum',nformat(#.00%)

将响应百分比和个案百分比两列的数字格式设置为保留两位的百分比

4.最后效果

跑上述代码的效果(多个多选题变量P3Q2 P3Q11 P3Q27)后：

mrtab.gif

5. 补充

根据实际需求修改，最终可实现批量导出多份数据的多个变量的频率结果~
其实，putexcel命令stata15就有了，一直没有仔细研究，现在发现这和分析后的存储结果以及矩阵很相关~感觉更理解stata里的矩阵了。
目前，还体验过的stata16其他功能：
1. do文件：自动补全命令；
2. 数据编辑窗口：可以手动调节宽度；
3. 和python的交互，这样可以用python爬数据后用stata进行统计分析，或者用stata将分析结果导出excel，再用python进行调整；（刚学完python爬数据，到时候再写写stata和python的交互）
4. 可以在内存中同时存多个数据，命令frame;
预期接下来：
stata结果导入excel-交叉分析
 stata结果导入excel-描述统计
 stata结果导入excel-方差分析