策略说明:
本策略是基于均线和K线形态的高低点突破系统
系统要素:
1. 根据价格与快速均线和慢速均线的关系来判断大的趋势，价格在上为多头趋势，在下为空头趋势
2. 根据2根K线收盘位置构成的形态来判断小趋势，第一根收盘靠近低点第二根收盘靠近高点为上涨趋势，否则为下跌趋势
3. 最近2根K线的高低点形成的通道
入场条件:
1. 大趋势为多头趋势，且K线形态也为多头趋势时，突破通道高点做多
2. 大趋势为空头趋势，且K线形态也为空头趋势时，突破通道低点做空
出场条件:
1. 开多以开仓BAR的最近N根BAR的低点作为止损价
开空以开仓BAR的最近N根BAR的高点作为止损价
2. 盈利超过止损额的一定倍数止盈
这程序化系统大周期的的结果很差，5min的测试相对好点，下面是做多代码及解读如下：
Params
Numeric FastLength(8); // 声明数值参数FastLength，初值8，快速均线周期。//
Numeric SlowLength(40); //声明数值参数SlowLength，初值40， 慢速均线周期。//
Numeric RiskLength(2); //声明数值参数RiskLength，初值2， 止损通道的周期数。//
Numeric ProfitFactor(2); //声明数值参数ProfitFactor，初值2， 止盈相对止损的倍数。//
Vars
NumericSeries MA_Fast; // 声明数值序列变量MA_Fast，即快速均线。//
NumericSeries MA_Slow; // 声明数值序列变量MA_Slow，即慢速均线。//
Numeric Range; // 声明数值变量Range，K线波动范围。//
BoolSeries Condition1; //声明布尔型序列变量Condition1，即 条件1。//
BoolSeries Condition2; // 声明布尔型序列变量Condition2，即条件2。//
NumericSeries HH; // 声明数值序列变量HH，即周期的高点。//
NumericSeries LL; // 声明数值序列变量LL，即周期的低点。//
NumericSeries LongRisk; // 声明数值序列变量LongRisk，止损时的风险额。//
Begin
If(!CallAuctionFilter()) Return;// 集合竞价和小节休息过滤。//
// 计算及输出均线指标。//
MA_Fast = Average(Close,FastLength);//求快速均线。//
MA_Slow = Average(Close,SlowLength);//求慢速均线。//
PlotNumeric("Ma_Fast",MA_Fast);//画快速线。//
PlotNumeric("Ma_Slow",MA_Slow);//画慢速线。//
Range = High - Low;// 每根K线的波动范围。//
// K线形态判断的2个条件。//
Condition1 = Close <= Low + 0.25 * Range;//运算逻辑是从右边往左边，=这个逻辑符号一般都是最后赋值的。//
Condition2 = Close >= High - 0.25 * Range;//同上解读。//
// 计算周期的高低点。//
HH = Highest(High,2);//计算2周期的最高点。//
LL = Lowest(Low,RiskLength);//计算2周期的最低点。//
If(MarketPosition == 0 And Condition1[2] And Condition2[1] And Close[1] > MA_Fast[1] And Close[1] > MA_Slow[1] And Vol > 0)// 开仓条件。//
{
If(High >= HH[1] + MinMove * PriceScale)//这也是开仓条件，也是进场价的条件。//
{
Buy(0, Max(Open,HH[1] + MinMove * PriceScale));//开仓买入。//
LongRisk = LL[1] - MinMove * PriceScale;//止损计算公式。//
}
}
// 平仓。//
If(MarketPosition == 1 And BarsSinceEntry > 0 And Vol > 0)//持有多单，建仓数位大于0，成交量大于0.//
{
If(High >= EntryPrice + ProfitFactor * (EntryPrice - LongRisk)) // 止盈条件。//
{
Sell(0, Max(Open,EntryPrice + ProfitFactor * (EntryPrice - LongRisk)));//平仓。//
}
// 止损。//
Else If(Low <= LongRisk)//假如当前最低价小于等于止损价的。//
{
Sell(0, Min(Open,LongRisk));//平仓。//
}
}
End
做空代码及结果如下：
Params
Numeric FastLength(8);
Numeric SlowLength(40);
Numeric RiskLength(2);
Numeric ProfitFactor(2);
Vars
NumericSeries MA_Fast;
NumericSeries MA_Slow;
Numeric Range;
BoolSeries Condition1;
BoolSeries Condition2;
NumericSeries HH;
NumericSeries LL;
NumericSeries ShortRisk;
Begin
If(!CallAuctionFilter()) Return;
MA_Fast = Average(Close,FastLength);
MA_Slow = Average(Close,SlowLength);
PlotNumeric("Ma_Fast",MA_Fast);
PlotNumeric("Ma_Slow",MA_Slow);
Range = High - Low;
Condition1 = Close >= High - 0.25 * Range;
Condition2 = Close <= Low + 0.25 * Range;
LL = Lowest(Low,2);
HH = Highest(High,RiskLength);
If(MarketPosition == 0 And Condition1[2] And Condition2[1] And Close[1] < MA_Fast[1] And Close[1] < MA_Slow[1] And Vol > 0)
{
If(Low <= LL[1] - MinMove * PriceScale)
{
SellShort(0, Min(Open,LL[1] - MinMove * PriceScale));
ShortRisk = HH[1] + MinMove * PriceScale;
}
}
If(MarketPosition == -1 And BarsSinceEntry > 0 And Vol > 0)
{
If(Low <= EntryPrice - ProfitFactor * (ShortRisk - EntryPrice))
{
BuyToCover(0, Min(Open,EntryPrice - ProfitFactor * (ShortRisk - EntryPrice)));
}
Else If(High >= ShortRisk)
{
BuyToCover(0, Max(Open,ShortRisk));
}
}
End
