Unity Shader 逐顶点Phong高光反射（六）

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

Phong逐顶点光照.jpg

Phong逐顶点光照、Phong逐像素光照、Blinn-Phong逐像素光照：

Phong逐顶点光照、Phong逐像素光照、Blinn-Phong逐像素光照.jpg

Phong高光反射公式：
$Cspecular=(Clight⋅Mspecular)max(0,\hat{v}.\hat{r})^{mgloss}$
$Clight$ ：入射光颜色；
$Mspecular$ ：高光反射颜色；
$\hat{v}$ ：单位视线向量；
$\hat{r}$ ：单位反射向量，可以由表面法线 $\hat{n}$ 和光源方向 $\hat{I}$ 计算而得：
$\hat{r}$ = 2( $\hat{n}$ . $\hat{I}$ ) $\hat{n}$ - $\hat{I}$ ，CG中可直接使用reflect获得；
$mgloss$ ：反射系数；

Shader代码：

// Phong逐顶点高光反射
// 注意：逐顶点计算出的高光部分会不平滑，因为高光反射部分是非线性的，
// 而在顶点着色器中计算光照再进行插值的过程是线性的
Shader "Custom/Specular/PhongSpecularVertex"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) // 漫反射颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
        _Gloss ("Gloss", Range(8, 256)) = 20 // 高光区域大小
    }
    
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;
            
            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 模型空间下的顶点坐标
                float3 normal: NORMAL; // 模型空间下的法线
            };
            
            // 顶点着色器函数传递给片元着色器函数的数据
            struct  v2f
            {
                float4 pos: SV_POSITION; // 裁剪空间下的顶点坐标
                fixed3 color: COLOR; // 颜色
            };
            
            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点坐标从模型空间转换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间转换到世界空间下，然后归一化
                // 等价于fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                float3 worldNormal = UnityObjectToWorldNormal(v.normal);
                
                // 获得世界空间下单位光方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0);
                
                // 计算漫反射
                // 兰伯特公式：Id = Ip * Kd * N * L
                // IP：入射光的光颜色；
                // Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
                // N：单位法向量，L：单位光向量
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
                
                // 计算反射方向
                // CG的reflect函数的入射方向要求是顶点指向光源，所以先取反
                fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
                
                // 计算观察方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
                
                // 计算高光反射
                // Phong高光反射公式：
                // Cspecular=(Clight ⋅ Mspecular)max(0,v.r)^mgloss
                // Clight：入射光颜色；
                // Mspecular：高光反射颜色；
                // v：单位视线向量；
                // r：单位反射向量，可以由表面法线n和光源方向l计算而得：
                // r = 2(n . I)n - I; CG中可直接使用reflect获得
                // mgloss：反射系数；
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
                
                // 计算颜色
                o.color = diffuse + specular + UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                return o;
            }
            
            // 片元着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                return fixed4(i.color, 1);
            }
            
            ENDCG
            
        }
    }
}

最后编辑于：2021.01.12 22:29:41