Unity的基础光照模型
1.光照的概念
模拟真实的光照环境来生成一张图像，需要考虑3种物理现象：
首先，光线从光源中发射出来；
然后，光线和场景中的一些物体相交（散射，吸收）；
最后，摄像机吸收了一些光，产生一张图像。
a.光源
实时渲染中，把光源当成没有体积的店，用l表示它的方向，且用辐照度来量化光。计算光照模型时，需要知道一个物体表面的辐照度，而物体表面往往是和l不垂直的，我们可以使用光源方向l和表面法线n之间的夹角的余弦值来得到。需要注意的是，这里默认方向矢量的模都为1。下图显示了使用余弦值来计算的原因。
b.吸收和散射
光线由光源发出后，会与物体发生相交，结果有两个：散射和吸收。
散射有两种方向，一是散射到物体内部，这种称为折射或者投射；二是散射到外部，被称为反射。
为了区分两种不同的散射方向，在光照模型中使用不同的部分计算他们：高光反射和漫反射。
2.标准光照模型
a.Phong光照模型
Phong光照模型只关心直接光照，即从光源发射出来照射到物体表面后，经过物体表面的一次反射直接进入摄像机的光线。
基本方法：进入相机的光线 = 自发光（emissive）+高光反射（specular）+漫反射（diffuse）+环境光（ambient)
公式：C = Cemissive + Cspecular + Cdiffuse + Cambient
Cambient：环境光。在标准光照模型中，我们使用环境光来模拟那些经过多个物体反射进入摄像机的间接光照。
Cemissive：自发光。由光源直接发射进入摄像机的光线。
Cdiffuse：漫反射。 被物体表面随机散射到各个方向的光线。
Cdiffuse = (Clight · Mdiffuse)max(0, n·I)
clight是光源颜色， mdiffuse是材质的漫反射颜色，n是表面法线，I是指向光源的单位矢量。
Cspecular：高光反射。这里的高光反射是一种经验模型，并不完全符合真实世界的高光反射。
Cspecular = (Clight·Mspecular)max(0, v·r) ^ gloss
gloss是材质的光泽度，控制高光区域的大小；mspecular是材质的高光反射颜色；clight是光源的颜
色和强度
b. Blinn-Phong光照模型
Blinn在计算高光反射时与Phong模型不同。
Blinn模型引入一个新的矢量h,他是通过对v和I取平均再归一化得到的。
h = (v + l) / | v + l |
Cspecular = (Clight · Mspecular)max(0, n·h)^gloss
优势：相机和光源距离足够远的花，Blinn快于Phong。
c.半兰伯特模型
Cdiffuse = (Clight·Mdiffuse)(0.5(n·I)+0.5)
进行了简单修改，把n·I的结果从[-1, 1]映射到了[0, 1]，在背光面(原本漫反射为0的地方)也有了明暗变化。
没有任何的物理依据，仅仅是视觉加强技术。
d.逐顶点光照和逐像素光照
逐顶点光照：我们在每个顶点上计算光照，然后在渲染图元内部进行线性插值，最后输出成像颜色。
逐像素光照：以每个像素为基础，得到它的发现，然后进行光照模型的计算。
如何选择：逐顶点光照计算量小于逐像素光照，但是当光照模型中存在非线性的计算时，逐顶点光照会出现问题。
d.模型对比结果
下图可见，Blinn-Phong 光照模型的高光反射部分看起来更大、更亮一些。在实际渲染中，绝大多数情况都会选择Blinn-Phong光照模型。这两种模型都是经验模型，即使我们不应该认为Blinn-Phong模型是对“正确的”Phong模型的近似。实际上，在一些情况下，Blinn-Phong模型更符合实验结果。
3.核心shader代码
Blinn-Phong模型（环境光+漫反射+高光反射）
Shader "BlinnPhongLevel"
{
Properties
{
_Diffuse("Diffuse", Color) = (1, 1, 1, 1)
_Specular("Specular", Color) = (1, 1, 1, 1)//控制材质的高光反射颜色
_Gloss("Gloss", Range(8.0, 256)) = 20 //控制高光区域大小
}
SubShader
{
Tags { "LightMode" = "ForwardBase" }
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
};
v2f vert(a2v v) {
v2f o;
// Transform the vertex from object space to projection space
o.pos = UnityObjectToClipPos(v.vertex);
//Tramsform the normal fram object space to world space
o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
//Transform the vertex from object space to world space
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
fixed4 frag(v2f i) : SV_Target
{
////get ambient term;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//get the normal in world space
fixed3 worldNormal = normalize(i.worldNormal);
//get the light direction in world space
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
//Compute diffuse term
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
// Get the reflect direction in world space 获取反射方向
//fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
// Get the view direction in world space 获取视角方向
//_WorldSpaceCameraPos：获取世界空间摄像机位置
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
fixed3 halfDir = normalize(worldLightDir + viewDir);
// Compute specular term
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color, 1.0);
}
ENDCG
}
}
Fallback "Specular"
}
4.常用函数
