- 法线纹理一般是为了让模型有视觉上的凹凸效果，但是模型实际不是具有凹凸面的，只是在计算光照时，让模型不同位置根据法线值的不同，得到凹凸感的光照效果。法线纹理中保存的可能是模型空间中的法线值，这种法线纹理是五颜六色的，因为它的法线值在（-1，1）之间，经过映射后得到（0,1）之间的值，颜色是多种的。而另一种法线纹理保存的是模型中每个顶点的切线空间中法线扰动方向，又因为模型中大部分顶点法线不需要扰动，所以转换到切线空间中法线方向仍为（0,0,1），变换后为（0.5,0.5,1），因此这种法线纹理大都为偏蓝色。
- 在计算光照时有两种选择，一种是在切线空间中计算，即在vertex shader中将光照计算需要的光照方向、视线方向、模型顶点世界坐标以及模型顶点中保存的法线方向变换到切线空间中，然后在fragment shader中对法线纹理BumpTex进行采样，得到法线纹理中法线normal，再根据经典光照模型计算出ambient，diffuse和specular。
- 在unity shader中使用法线纹理有一些要注意的地方，如法线纹理导入到unity中如果被设置为normalMap格式时，应该使用的解压函数，计算binormal时要确定叉乘后的方向等，以及求float3x3的模型->切线空间变换矩阵等。在实例中给予注释说明。
- 使用基于切线空间的法线纹理的计算复杂点在于光照计算上，因为我们需要把切线空间的法线变换到世界空间（或者翻过来把世界空间中的光线视点等变换到切线空间），而求这些变换矩阵时就要仔细小心（也算对矩阵变换计算的一个自我检验）。
- 在tangentSpace中计算光照实例
Shader "FFD/BumpMap/NormalMapTangentSpace"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
_BumpTex ("BumpMap",2D) = "bump" {}
_BumpScale ("BumpScale",Range(-1,1)) = 0
_Gloss ("GLoss",range(1,30)) = 20
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "lighting.cginc"
#include "autolight.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float4 vTangent : TANGENT;
float3 vNormal : NORMAL;
};
struct v2f
{
float4 uv : TEXCOORD0;
float4 vertex : SV_POSITION;
// float3 tangentNormal : TEXCOORD1;
float3 tangentView : TEXCOORD2;
float3 tangentLight : TEXCOORD3;
};
sampler2D _MainTex;
sampler2D _BumpTex;
float4 _MainTex_ST;
float4 _BumpTex_ST;
float _BumpScale;
float _Gloss;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv.xy = TRANSFORM_TEX(v.uv, _MainTex);
o.uv.zw = TRANSFORM_TEX(v.uv,_BumpTex);
float3x3 objToTangent;
float3 bitNormal = normalize(cross(v.vNormal,v.vTangent.xyz)*v.vTangent.w);
float3 vNormal = normalize(v.vNormal);
float3 vTangent = normalize(v.vTangent);
//计算object->tangent转换矩阵,构建一个3x3的矩阵，因为变换的是向量，没必要用4x4的矩阵。
//这个矩阵使用的是三个向量分布为矩阵的每一行(考虑 world->camera )
objToTangent = float3x3(vTangent.xyz,bitNormal,vNormal);
//计算object空间光线方向或者用内置函数计算
float3 objLight = mul((float3x3)unity_WorldToObject,_WorldSpaceLightPos0.xyz);
// float3 objLight = ObjSpaceLightDir(v.vertex);
//计算object空间view方向
float3 objView = mul(unity_WorldToObject,float4(_WorldSpaceCameraPos.xyz,1))-v.vertex.xyz;
o.tangentLight = mul(objToTangent,objLight);
o.tangentView = mul(objToTangent,objView);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
// sample the texture
fixed4 col = tex2D(_MainTex, i.uv);
float3 tangentLight = normalize(i.tangentLight);
float3 tangentView = normalize(i.tangentView);
//如果没有在unity中对纹理设置为normalTexture，那么就要手动解析切线空间中的法线
fixed4 colBump = tex2D(_BumpTex,i.uv.zw);
float3 tangentNormal;
//此时没有被压缩，所以tangentNormal.xyz = colBump*2-1;
//tangentNormal = UnpackNormal(colBump);//如果设置了就用内置函数。
tangentNormal.xy = (colBump.xy*2-1.0) * _BumpScale;
tangentNormal.z = sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
//计算光照
tangentNormal = normalize(tangentNormal);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.xyz * saturate(dot(tangentLight,tangentNormal));
float3 H = normalize(tangentView + tangentLight);
float3 specular=_LightColor0.xyz * pow(saturate(dot(tangentNormal,H)),_Gloss);
col = fixed4(col.xyz*(ambient+diffuse+specular),1);
return col;
}
ENDCG
}
}
FallBack "Specular"
}
- 在切线空间计算光照有一个问题就是当物体在不统一缩放情况下会产生光照错误的情况，因此unity5.x内置的shader中都将光照计算放到世界空间中进行了。世界空间法线纹理光照计算如下例，注意的地方是因为要将切线空间中的法线变换到世界空间，就要在vert shader中将变换矩阵求出来，因为vert->frag数据传递最多是float4类型的向量，所以定义3个float3的向量来组成tangent->world转换矩阵（也可以充分利用寄存器空间，在已用三个寄存器w分量中存储worldPos的三个分量）。
Shader "FFD/BumpMap/NormalMapWorldSpace"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
_BumpTex ("BumpTex",2D) = "bump"{}
_Gloss("Gloss",range(1,30)) = 1
_BumpScale ("BumpScale",range(-1,1)) =0
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "lighting.cginc"
#include "autolight.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float4 tangent :TANGENT;
float3 normal : NORMAL;
};
struct v2f
{
float4 vertex : SV_POSITION;
float4 uv : TEXCOORD0;
float4 worldVertexPos : TEXCOORD1;
float3 TtoW0 : TEXCOORD2;
float3 TtoW1 : TEXCOORD3;
float3 TtoW2 : NORMAL;
};
sampler2D _MainTex;
sampler2D _BumpTex;
float4 _MainTex_ST;
float4 _BumpTex_ST;
float _Gloss;
float _BumpScale;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv.xy = TRANSFORM_TEX(v.uv, _MainTex);
o.uv.zw = TRANSFORM_TEX(v.uv,_BumpTex);
o.worldVertexPos = mul(unity_ObjectToWorld,v.vertex);
float3 worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
float3 worldTangent = mul(unity_ObjectToWorld,v.tangent.xyz);
float3 worldBitNormal = cross(worldNormal,worldTangent)*v.tangent.w;
o.TtoW0 = float3(worldTangent.x,worldBitNormal.x,worldNormal.x);
o.TtoW1 = float3(worldTangent.y,worldBitNormal.y,worldNormal.y);
o.TtoW2 = float3(worldTangent.z,worldBitNormal.z,worldNormal.z);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
// sample the texture
fixed4 col = tex2D(_MainTex, i.uv.xy);
float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
float3 worldView = normalize(_WorldSpaceCameraPos.xyz-i.worldVertexPos.xyz);
//对bump纹理采样得到tangent空间下的normal；
float4 colBump = tex2D(_BumpTex,i.uv.zw);
//如果将法线图设置为normalMap，就用这个函数，如果没设置，用此函数会得到错误的结果
float3 normal = UnpackNormal(colBump);
normal.xy = normal.xy*_BumpScale;
normal.z = sqrt(1.0-dot(normal.xy,normal.xy));
//构建Tangent->World变换矩阵,或者直接相乘
float3x3 TtoW = float3x3(i.TtoW0,i.TtoW1,i.TtoW2);
float3 worldNormal = normalize(mul(TtoW,normal));
//计算光照
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.xyz * saturate(dot(worldNormal,worldLight));
float3 H = normalize(worldView+worldLight);
fixed3 specular = _LightColor0.xyz * pow(saturate(dot(H,worldNormal)),_Gloss);
col = col*fixed4(ambient+diffuse+specular,1);
return col;
}
ENDCG
}
}
FallBack "Specular"
}
