通常来说，透明物体是不需要写深度的，例如：

• 透明物体与非透明物体间的渲染不会有问题
  因为所有透明物体会在所有非透明物体之后渲染。

• 大多数情况下，透明物体之间的渲染也不会有问题
  因为，所有透明物体按由远及近的顺序渲染，所以不会出现前面的透明物体挡住后面的透明物体，导致后面的透明物体不显示。

但有些情况下，透明物体必须要写深度，例如：

• 两个透明物体间有交叉
  如果不写深度，深度则无法正确比较，就会出现遮挡关系错误的现象。

图1为俯视角度看两面片的实际位置关系。红色透明面片与蓝色透明面片相交，一部分红色面片在前，另一部分红色面片在后。

1

图2为不写深度时相机渲染的结果。蓝色面片完全遮住了红色面片，与实际的前后关系不符。

2

图3为两个面片都写入深度之后的渲染结果，看似正常，但会发现透过左侧红色的面片看不到紫色的面片了。因为红色面片先绘制，写了深度，当紫色面片绘制时深度测试失败，会被丢弃。

3

• 自身有交叉的透明物体

4.png

图4为模型透明效果。想要保证透明物体的渲染结果正确，必须要让远离相机的面先绘制，近相机的面后绘制。然而一个物体内部所有三角面的渲染顺序是由mesh中定义的三角面顺序决定的，所以无法保证前后渲染关系。此时如果不借助写深度，是无法实现正确的渲染的。

思路：模型要跟自身深度值比较，在一个Pass内不可能做到。所以先用一个pass记录模型的深度值。第二个pass再跟上一个pass中记录的自身深度进行比较。这样就可以分清面片的前后关系了。

5

图5是修改后的渲染结果，这才正常。

Shader "Transparent"
{
    Properties
    {
        _MainTex("MainTex", 2D) = "white"{}

        _Alpha("Alpha", Range(0,1)) = 1
    }

    SubShader
    {
        Tags{"Queue"="Transparent" "RenderType"="Opaque"}
        LOD 200
        Cull Back
        
        Pass 
        {
            ZWrite On
            ColorMask
        }

        Pass
        {
            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
                
                #include "UnityCG.cginc"
                #pragma vertex vert
                #pragma fragment frag

                sampler2D _MainTex;
                half _Alpha;

                struct V2F
                {
                    float4 pos:POSITION;
                    float2 uv:TEXCOORD0;
                };

                V2F vert(appdata_img i)
                {
                    V2F o;

                    o.pos = UnityObjectToClipPos(i.vertex);
                    o.uv = i.texcoord;

                    return o;
                }

                fixed4 frag(V2F i):COLOR
                {
                    fixed4 col = tex2D(_MainTex, i.uv);
                    col.a = _Alpha;

                    return col;
                }

            ENDCG
        }
    }
}

透明渲染写深度总结

• 不写深度
  a. 当一个物体自身没有穿插，两个物体间没有穿插时，不写深度没有问题。

  b. 当两个物体间有穿插时，会导致一个物体完全挡住另外一个物体，与现实不符。

• 写深度
  a. 当一个物体自身有穿插时，使用两个pass，才可以保证透明正常，且不会透过物体的正面看到后面的面。

  b. 但是写了深度后，这两个物体穿插时，会导致不能透过一个角色看到另外一个角色。

两物体没有穿插时正常

两物体有穿插时就不正常了

最后

• 正常情况下，透明物体渲染不需要写深度
• 特殊情况下，根据需求才写深度，虽然会带来小问题，但也还可以接受。