win10 1909更新之时，提示我们无法更新系统保留的分区

无法更新系统保留的分区

EFI 100MB
MSR 16MB
Recovery 529MB

因此导致没有足够的空间进行更新。所以才有了接下来安装win10系统前的手动分区操作。可以把之前的默认分区方案适当的扩大一些，如图所示：

diskpart手动分区结果

首先，下载win10镜像，制作启动优盘，在win10安装界面出来之后，按快捷键 SHIFT+F10，进入cmd命令行中，然后输入diskpart回车，具体的分区过程如下：

# 从cmd进入diskpart分区工具命令行中
diskpart
# 列出当前所有存在的硬盘 
list disk 
# 这里选择0号硬盘作为操作系统所在的硬盘
select disk 0
# 删除所有分区，在此之前需要确保已经备份好整个硬盘的资料
clean
# 转换硬盘为GPT格式（如果已经是GPT格式，则跳过此操作）
convert gpt

# 进入正题

# EFI
create partition efi size=512 # 创建一个EFI分区，大小为512MB
# assign letter=b # 设置分区盘符，安装系统时可省略这一步
format quick fs=fat32 label="EFI" # 格式化EFI分区文件系统为FAT32，标签为EFI

# MSR
# 对于小于 16 GB 的磁盘，MSR 分区为 32 MB。对于大于 16 GB 的磁盘，MSR 分区为 128 MB。
# 对于在GPT磁盘上的Windows操作系统，MSR分区不是必须的，可以删除不受影响。
create partition msr size=128  # 创建一个MSR分区，大小为128MB，Win10 1909 默认是16M

# Recovery
# recovery 是系统还原分区，删除掉这个分区你将无法还原初始系统；
create partition primary size=650 # 创建一个主分区，大小为650MB Win10 1909 默认是529M
format quick fs=ntfs label="Recovery" # 格式化Recovery分区文件系统为NTFS，标签为Recovery
# assign letter="R" # 设置分区盘符，安装系统时可省略这一步
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"  # 设置主分区类型为恢复分区
gpt attributes=0x8000000000000001   #修改主分区属性为“受保护”，8 和 1 之间有14个0

# 上述全部设置完成之后，退出即可
exit

所有的操作记录：

Microsoft Windows [版本 10.0.18362.592]
(c) 2019 Microsoft Corporation。保留所有权利。
X:\Sources>diskpart
Microsoft Windows 版本 10.0.18362.1

Copyright (c) Microsoft Corporation.
在计算机上：MINWINPC

DISKPART> list disk
 磁盘 ###  状态             大小       可用      Dyn      Gpt
 -------- ---------------- ---------  -------- -------- -----
 磁盘 0    联机               931 GB      930 GB             *
 磁盘 1    联机               953 GB      953 GB             *
 磁盘 2    联机                14 GB        0 GB             *

DISKPART> select disk 0
磁盘 0 现在是所选磁盘。
DISKPART> clean
Diskpart 成功地清除了磁盘。
DISKPART> convert gpt
Diskpart 已将所选磁盘成功地转更换为 GPT 格式。
DISKPART> create partition efi size=512
Diskpart 成功地创建了指定分区。
DISKPART> format quick fs=fat32 label="EFI"
 100 百分比已完成
Diskpart 成功格式化该卷。
DISKPART> create partition msr size=128
Diskpart 成功地创建了指定分区。
DISKPART> create partition primary size=650
Diskpart 成功地创建了指定分区。
DISKPART> format quick fs=ntfs label="Recovery"
 100 百分比已完成
Diskpart 成功格式化该卷。
DISKPART> set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
Diskpart 成功设置了分区 ID。
DISKPART> gpt attributes=0x8000000000000001
Diskpart 成功地将属性分配给选择的 GPT 分区。
DISKPART> exit

退出后，Windows安装程序中刷新一下磁盘列表，然后即可正常安装win10啦！
安装完之后更新一切正常！