本篇笔记是Learning Perl第七版第14章部分内容
在Learning Perl这本书的刚开始，作者提到perl是一个很好的用来解决文本工作的编程语言，这一章主要讲的就是对文本的一些处理操作。
（一）利用index寻找字符串中的substring
index功能可以帮助我们在字符串中寻找某一个部分的定位。举个简单的例子：
my $stuff = "Howdy world!";
my $where = index($stuff, "wor");
在上面的字符串里寻找wor这一部分。这两行代码应该返回的数字是6，因为在wor部分的前面有6个字符位置（5个字母加一个空格）。index功能总是报告第一个substring发生的位置。
my $stuff = "Howdy world!";
my $where1 = index($stuff, "w"); # $where1 gets 2
my $where2 = index($stuff, "w", $where1 + 1); # $where2 gets 6
my $where3 = index($stuff, "w", $where2 + 1); # $where3 gets -1 (not found)
上面的代码说明的是在字符串里寻找w字母，当我们寻找第三个w的时候，index会返回-1，说明没有更多的w出现的字符串中了。下面是一个例子：
#!/usr/bin/perl
use warnings;
use strict;
use v5.24;
my $stuff = "Howdy world!"; #指定字符串
my @where = (); #设置空数组，以存放位置信息
my $where = -1; #将初始位置设置为-1，代表没有substring在字符串里出现
while( 1 ) { #while(1)代表无限循环
$where = index( $stuff, 'w', $where + 1 ); #每碰到一个w，就计算一次
last if $where == -1; #如果没有更多的w出现，index则返回-1
push @where, $where; #每碰到一个w，就往$where里存放一个位置信息
}
say "Positions are @where";#最后打印所有位置
运行上面的脚本：
$ ./practice1.pl
Positions are 2 6
rindex功能可以从字符串的最后开始，往前面计算位置，例如：
my $fred = "Yabba dabba doo!";
my $where1 = rindex($fred, "abba"); # $where1 gets 7
my $where2 = rindex($fred, "abba", $where1 - 1); # $where2 gets 1
my $where3 = rindex($fred, "abba", $where2 - 1); # $where3 gets -1
举个例子：
#!/usr/bin/perl
use warnings;
use strict;
use v5.24;
my $fred = "Yabba dabba doo!";
my @where = ();
my $where = length $fred; #这次的$where初始值不是-1了，而是这个字符串的长度
while(1) {
$where = rindex($fred, "abba", $where - 1 );
last if $where == -1;
push @where, $where;
}
say "Positions are @where";
运行上面的脚本：
$ ./practice1.pl
Positions are 7 1
（二）使用substr取子字符串
substr的基本格式是：
my $part = substr($string, $initial_position, $length);
它有三个参数，第一个参数是你要操作的字符串，第二个参数是起始位置（比如index的返回值），第三个参数是你要取的substring的长度。比如：
my $mineral = substr("Fred J. Flintstone", 8, 5); # gets "Flint"
my $pebble = substr "Fred J. Flintstone", 13; # gets "stone" #如果你要取到字符串结尾，就可以省略第三个参数
也可以从字符串结尾作为起始位置来取substring：
my $out = substr("some very long string", -3, 2); # $out gets "in"
当然你可以把index和substr结合一起用：
my $long = "some very very long string";
my $right = substr($long, index($long, "l") );
这时你得到的结果是：long string。
另外，你可以用substr来替换原字符串里的内容：
my $string = "Hello, world!";
substr($string, 0, 5) = "Goodbye"; # "Goodbye, world!"
如果你的长度参数设置为0，那么就是在原字符串里插入字符：
substr($string, 9, 0) = "cruel"; # "Goodbye, cruel world!";
（三）Advanced Sorting（排序）
给定一列数字，将它们升序排列，并打印出list，使list右对齐。
#!/usr/bin/perl
use warnings;
use strict;
use v5.24;
my @numbers = qw / 17 1000 04 1.50 3.14159 -10 1.5 4 2001 90210 666/; #给定一列数字
sub by_numeric {$a <=> $b}; #子程序，排序数字，按升序排列
foreach (sort by_numeric @numbers){
printf "%10s\n",$_; #使用printf打印，共10个字符的宽度，右对齐
}
运行该脚本：
$ ./practice1.pl
-10
1.50
1.5
3.14159
04
4
17
666
1000
2001
90210
除了对数字排列，还可以对字符进行排列。下面的例子是一些人的名字，一般是由first name和last name组成。先对last name进行排列，也就是对value先进行排列，在value相同的情况下，对key进行排列：
fred flintstone Wilma Flintstone Barney Rubble
betty rubble Bamm-Bamm Rubble PEBBLES FLINTSTONE
脚本：
#!/usr/bin/perl
use warnings;
use strict;
use v5.24;
my %last_name = qw{
fred flintstone Wilma Flintstone Barney Rubble
betty rubble Bamm-Bamm Rubble PEBBLES FLINTSTONE
}; #给定的hash
my @sort_by_last_name = sort {
"\L$last_name{$a}" cmp "\L$last_name{$b}" #对last name进行排列，cmp用于字符排列，\L表示对字母大小写不敏感
or
"\L$a" cmp "\L$b" #再对first name进行排列
} keys %last_name;
foreach(@sort_by_last_name){
print "$last_name{$_},$_\n"; #打印hash
}
运行脚本：
$ ./practice1.pl
flintstone,fred
FLINTSTONE,PEBBLES
Flintstone,Wilma
Rubble,Bamm-Bamm
Rubble,Barney
rubble,betty
