上次说到很简单的shader，这次来用颜色可视化模拟和顶点相关的数据，代码如下：

Shader "Unity Shaders Book/Chapter 5/False Color" {
    SubShader {
        Pass {
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            
            struct v2f {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR0;
            };
            
            v2f vert(appdata_full v) {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                
                // Visualize normal
                o.color = fixed4(v.normal * 0.5 + fixed3(0.5, 0.5, 0.5), 1.0);
                
                // Visualize tangent
                o.color = fixed4(v.tangent.xyz * 0.5 + fixed3(0.5, 0.5, 0.5), 1.0);
                
                // Visualize binormal
                fixed3 binormal = cross(v.normal, v.tangent.xyz) * v.tangent.w;
                o.color = fixed4(binormal * 0.5 + fixed3(0.5, 0.5, 0.5), 1.0);
                
                // Visualize the first set texcoord
                o.color = fixed4(v.texcoord.xy, 0.0, 1.0);
                
                // Visualize the second set texcoord
                o.color = fixed4(v.texcoord1.xy, 0.0, 1.0);
                
                // Visualize fractional part of the first set texcoord
                o.color = frac(v.texcoord);
                if (any(saturate(v.texcoord) - v.texcoord)) {
                    o.color.b = 0.5;
                }
                o.color.a = 1.0;
                
                // Visualize fractional part of the second set texcoord
                o.color = frac(v.texcoord1);
                if (any(saturate(v.texcoord1) - v.texcoord1)) {
                    o.color.b = 0.5;
                }
                o.color.a = 1.0;
                
                // Visualize vertex color
//              o.color = v.color;
                
                return o;
            }
            
            fixed4 frag(v2f i) : SV_Target {
                return i.color;
            }
            
            ENDCG
        }
    }
}

从#include "UnityCG.cginc"说起，它是包含了unity的一个内置文件UnityCG.cginc，在unity的安装目录 /Data/CGIncludes/UnityCG.cginc下面能够找到。而appdata_full 结构体就在其中定义了
v2f和fixed4决定了vert和fragment函数的输出类型
vert函数具体代码中，v.normal 可以通过加权平均共享该顶点的所有三角形面法线得到，因为v.normal 的各个分量范围是[-1,1],而颜色RGB的分量范围是[01,],于是就要解决这个范围映射问题，所以就有了o.color = fixed4(v.normal * 0.5 + fixed3(0.5, 0.5, 0.5), 1.0);这样的代码，切线可视化类似，但需要主要的是切线是四维向量，具体可在Sahder笔记中查看，切线和副切线如何计算的可参照这个。
o.color = fixed4(v.texcoord.xy, 0.0, 1.0);是把顶点的第一组纹理坐标存到color中
o.color = frac(v.texcoord1);则是计算顶点第二组纹理各分量的小数部分，saturate意为返回一个[0, 1]范围内的数，如果x<0则返回0，如果x>1则返回1，否则返回x。
　　相信通过添加注释不同位置的代码，就能更直观的看到结果了。